Интеграция с 1С

Возвращаясь к решению от sayunot

// получаем определение сервиса и берем из него фабрику  
// ВетисAPI = http://api.vetrf.ru/schema/platform/services/ApplicationManagementService_v1.2.wsdl  
ОпределениеWS = WSСсылки.ВетисAPI.ПолучитьWSОпределения();  
  
// создаем врем. фабрику на основе пакетов из конфиги и web сервиса  
// нам нужны 2 пакета из ws, но пакет с application нужен локальный  
МассивURI = Новый Массив;  
МассивURI.Добавить("http://api.vetrf.ru/schema/cdm/application/ws-definitions");  
МассивURI.Добавить("http://api.vetrf.ru/schema/cdm/base/ws-definitions");  
  
ФабрикаWS = Новый ФабрикаXDTO(ОпределениеWS.ФабрикаXDTO.ЭкспортМоделиXDTO(МассивURI), ФабрикаXDTO.Пакеты);  
  
// добавим 2 пакета, которые нужны, но есть только локально  
Пакеты = Новый Массив;  
Пакеты.Добавить(ФабрикаXDTO.Пакеты.Получить("http://api.vetrf.ru/schema/cdm/mercury/applications"));  
Пакеты.Добавить(ФабрикаXDTO.Пакеты.Получить("http://schemas.xmlsoap.org/soap/envelope/"));  
Для Каждого Пакет Из ФабрикаWS.Пакеты Цикл  
    Пакеты.Добавить(Пакет);  
КонецЦикла;  
  
// создаем общую фабрику  
ФабрикаXD = Новый ФабрикаXDTO(, Пакеты);  
  
// создаем пробный узел Меркурия, MercuryApplicationRequest. используем теста ради  
// в реальности на месте этого запроса может (и должен) быть любой другой из этого пакета  
MercRequestDO = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/mercury/applications", "MercuryApplicationRequest");  
// я сразу инициализую все узлы объекта методом, что ниже, имхо там удобнее  
// ИнициализироватьОбъектXDTO(MercRequestDO, ФабрикаXD);  
  
// определяем свойства и их значения для заполнения.  
// можно, конечно, и напрямую указать для каждого свойства значение,  
// но т.к. запросы будут разные, проще для каждого составить свое соответствие  
// и использовать общий метод  
MercRequestPM = Новый Соответствие;  
MercRequestPM.Вставить("localTransactionId", вашID);  
MercRequestPM.Вставить("initiator/login", login);  
// тож мой локальный метод  
// ЗаполнитьСвойстваОбъектаXDTO(MercRequestDO, MercRequestPM);  
  
// создаем нужный запрос, инициализируем, заполняем свойства  
SubmitRequestDO = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application/ws-definitions", "submitApplicationRequest");  
  
ИнициализироватьОбъектXDTO(SubmitRequestDO, ФабрикаXD);  
  
SubmitRequestPM = Новый Соответствие;  
SubmitRequestPM.Вставить("apiKey", apiKey);  
SubmitRequestPM.Вставить("application/serviceId", "mercury-g2b.service");  
SubmitRequestPM.Вставить("application/issuerId", issuerID);  
SubmitRequestPM.Вставить("application/issueDate", ТекущаяДата());  
  
ЗаполнитьСвойстваОбъектаXDTO(SubmitRequestDO, SubmitRequestPM);  
  
// добавляем в блок data mercury request  
SubmitRequestDO.application.data.Добавить(ФормаXML.Элемент, MercRequestDO.Тип().URIПространстваИмен, "mercuryApplicationRequest", MercRequestDO);  
  
// создаем корневой узел, инициализируем  
EnvelopeDO = ФабрикаXD.Создать("http://schemas.xmlsoap.org/soap/envelope/", "Envelope");  
  
ИнициализироватьОбъектXDTO(EnvelopeDO, ФабрикаXD);  
  
// добавляем submitApplicationRequest в блок body и готово!)  
EnvelopeDO.body.Добавить(ФормаXML.Элемент, SubmitRequestDO.Тип().URIПространстваИмен, "submitApplicationRequest", SubmitRequestDO);  
  
// получившийся объект можем выгружать во что угодно и передавать каким угодно способом, например, так:  
ТелоXML = Новый ЗаписьXML;  
ТелоXML.УстановитьСтроку("UTF-8");  
  
ФабрикаXD.ЗаписатьXML(ТелоXML, EnvelopeDO);  
  
ЗапросWeb = Новый HTTPЗапрос("platform/services/ApplicationManagementService");  
ЗапросWeb.УстановитьТелоИзСтроки(ТелоXML.Закрыть());  
  
СоединениеWeb = Новый HTTPСоединение("api2.vetrf.ru", 8002, login, password,,Истина);  
ОтветWeb = СоединениеWeb.ОтправитьДляОбработки(ЗапросWeb);  
Если (ОтветWeb.КодСостояния = 200) Тогда // значит, все ок  
    // десериализуем  
    ОтветXML = Новый ЧтениеXML;  
    ОтветXML.УстановитьСтроку(ОтветWeb.ПолучитьТелоКакСтроку("UTF-8"));  
      
    MercAppDO = ФабрикаXD.ПрочитатьXML(ОтветXML, EnvelopeDO.Тип()).Body.submitApplicationResponse.application;  
      
    // возможные статусы:  
    // ACCEPTED   Заявка принята.  
    // IN_PROCESS Заявка обрабатывается.  
    // COMPLETED  Заявка успешно обработана.  
    // REJECTED   Заявка отклонена.  
    Если (MercAppDO.status = "ACCEPTED") Тогда  
        // тут шлем запрос на подтверждение  
    КонецЕсли;  
КонецЕсли;

Товарищи, подскажите, пожалуйста, неспециалисту: там, где шлем запрос на подтверждение, - как правильно вызвать метод submitApplicationRequest? Т.е. какое application ему надо передать в качестве параметра? Пробовал передать MercAppDO, но тут он снова ругался на ошибку SOAP, т.е. от чего пытались уйти - к тому и вернулись...

Application = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application", "Application");
Application.serviceId = "mercury-g2b.service";
Application.issuerId = issuerId;
Application.issueDate = ТекущаяДата();

ApplicationDataWrapper = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application", "ApplicationDataWrapper");
Application.data = ApplicationDataWrapper;

SubmitRequestDO = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application/ws-definitions", "submitApplicationRequest");

SubmitRequestDO.apiKey = apiKey;
SubmitRequestDO.Application = Application;

SubmitRequestDO.Application.data.Добавить(ФормаXML.Элемент, MercRequestDO.Тип().URIПространстваИмен, "MercuryApplicationRequest", MercRequestDO);

Что-то типа такого, может на мысль наведет

Проинициализировал MercRequestDO, не помогло... та же самая "Ошибка SOAP сервера".

zoertan wrote:Проинициализировал MercRequestDO, не помогло... та же самая "Ошибка SOAP сервера".

Непонятно где ошибка возникает? После отправки на сервер или при генерации xml?

esteem wrote:

zoertan wrote:Проинициализировал MercRequestDO, не помогло... та же самая "Ошибка SOAP сервера".

Непонятно где ошибка возникает? После отправки на сервер или при генерации xml?

Вот здесь (строчка выделена красным):

Если (MercAppDO.status = "ACCEPTED") Тогда
// тут шлем запрос на подтверждение
Прокси = WSСсылки.WSApplicationManagementsServiceTest.СоздатьWSПрокси("http://api.vetrf.ru/schema/cdm/application/service", "ApplicationManagementServiceBindingQSService", "ApplicationManagementServiceBindingQSPort");
Прокси.Пользователь = login;
Прокси.Пароль = password;
Результат = Прокси.submitApplicationRequest(SubmitRequestDO.apiKey, MercAppDO);
КонецЕсли;

zoertan wrote:

esteem wrote:

zoertan wrote:Проинициализировал MercRequestDO, не помогло... та же самая "Ошибка SOAP сервера".

Непонятно где ошибка возникает? После отправки на сервер или при генерации xml?

Вот здесь (строчка выделена красным):

Если (MercAppDO.status = "ACCEPTED") Тогда
// тут шлем запрос на подтверждение
Прокси = WSСсылки.WSApplicationManagementsServiceTest.СоздатьWSПрокси("http://api.vetrf.ru/schema/cdm/application/service", "ApplicationManagementServiceBindingQSService", "ApplicationManagementServiceBindingQSPort");
Прокси.Пользователь = login;
Прокси.Пароль = password;
Результат = Прокси.submitApplicationRequest(SubmitRequestDO.apiKey, MercAppDO);
КонецЕсли;

Так ты ответ хочешь получить. Как я понимаю смысл - Отправляешь заявку на выполнение, получаешь ID заявки и статус принята или нет. Потом надо подать запрос на получение результата выполнение заявки.
ResultRequest = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application/ws-definitions", "receiveApplicationResultRequest");
ResultRequest.apiKey = ;
ResultRequest.issuerId = ;
ResultRequest.applicationId = ;
и получаешь ответ что там с ней

Тут хорошо описано
http://help.vetrf.ru/wiki/%D0%9F%D0%BE%D0%B4%D1%81%D0%B8%D1%81%D1%82%D0%B5%D0%BC%D0%B0_%D0%BE%D0%B1%D1%80%D0%B0%D0%B1%D0%BE%D1%82%D0%BA%D0%B8_%D0%B7%D0%B0%D1%8F%D0%B2%D0%BE%D0%BA_%D0%B2_%D0%92%D0%B5%D1%82%D0%B8%D1%81.API#.D0.92.D0.BE.D0.B7.D0.BC.D0.BE.D0.B6.D0.BD.D1.8B.D0.B5_.D1.81.D1.86.D0.B5.D0.BD.D0.B0.D1.80.D0.B8.D0.B8

на гитхабе есть исходники выросшие из sayunot

mevgenym wrote:на гитхабе есть исходники выросшие из sayunot

А ссылку?)))

и получаешь ответ что там с ней

Это каким образом? Можно поподробнее, плиз, с этим ResultRequest?

А вот так это сделать правильно будет?

zoertan wrote:

и получаешь ответ что там с ней

Это каким образом? Можно поподробнее, плиз, с этим ResultRequest?

А вот так это сделать правильно будет?

Прокси = WSСсылки.WSApplicationManagementsServiceTest.СоздатьWSПрокси("http://api.vetrf.ru/schema/cdm/application/service", "ApplicationManagementServiceBindingQSService", "ApplicationManagementServiceBindingQSPort"); Прокси.Пользователь = login; Прокси.Пароль = password; Результат = Прокси.receiveApplicationResult(apiKey, issuerId, MercAppDO.applicationId)

Ну и получаешь ответ? Я сейчас делаю обработку работу со справочниками , а не с заявками. Запрос на результат - это примерно тотже запрос на подачу заявки. Вот пример кода, ответ получал дальше не разбирался.
ResultRequest = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application/ws-definitions", "receiveApplicationResultRequest");
ResultRequest.apiKey = apiKey;
ResultRequest.issuerId = issuerID;
ResultRequest.applicationId = "278448d7-f657-4aac-b4e7-1cef9f5a5151"; // Должен был получить при отправке заявки

EnvelopeDO = ФабрикаXD.Создать("http://schemas.xmlsoap.org/soap/envelope/", "Envelope");

Body = ФабрикаXD.Создать("http://schemas.xmlsoap.org/soap/envelope/", "Body");
EnvelopeDO.Body = Body;

EnvelopeDO.Body.Добавить(ФормаXML.Элемент, ResultRequest.Тип().URIПространстваИмен, "receiveApplicationResultRequest", ResultRequest);

ТелоXML = Новый ЗаписьXML;
ТелоXML.УстановитьСтроку("UTF-8");

ФабрикаXD.ЗаписатьXML(ТелоXML, EnvelopeDO);

ЗапросWeb = Новый HTTPЗапрос("platform/services/ApplicationManagementService");
ЗапросWeb.УстановитьТелоИзСтроки(ТелоXML.Закрыть());

СоединениеWeb = Новый HTTPСоединение("api2.vetrf.ru", 8002, login, password,,Истина);
ОтветWeb = СоединениеWeb.ОтправитьДляОбработки(ЗапросWeb);
Если (ОтветWeb.КодСостояния = 200) Тогда // значит, все ок
// десериализуем
ОтветXML = Новый ЧтениеXML;
ОтветXML.УстановитьСтроку(ОтветWeb.ПолучитьТелоКакСтроку("UTF-8"));

MercAppDO = ФабрикаXD.ПрочитатьXML(ОтветXML, EnvelopeDO.Тип()).Body.receiveApplicationResultResponse.application;

КонецЕсли;

Ну и получаешь ответ?

Ответ приходит, но там у него статус почему-то "REJECTED".

В-общем, так: у MercAppDO.status = "ACCEPTED", далее внутри этого условия пишу тот код, что привел выше, там ответ приходит, у получаемого объекта XDTO свойство "status" = REJECTED. Вот так.

zoertan wrote:

Ну и получаешь ответ?

Ответ приходит, но там у него статус почему-то "REJECTED".

В-общем, так: у MercAppDO.status = "ACCEPTED", далее внутри этого условия пишу тот код, что привел выше, там ответ приходит, у получаемого объекта XDTO свойство "status" = REJECTED. Вот так.

полученный ответ сохрани в xml, там будет видна и причина по которой запрос отклонен

zoertan wrote:

Ну и получаешь ответ?

Ответ приходит, но там у него статус почему-то "REJECTED".

В-общем, так: у MercAppDO.status = "ACCEPTED", далее внутри этого условия пишу тот код, что привел выше, там ответ приходит, у получаемого объекта XDTO свойство "status" = REJECTED. Вот так.

REJECTED Заявка отклонена.

полученный ответ сохрани в xml, там будет видна и причина по которой запрос отклонен

"Unsupported application data format" - что может значить?

zoertan wrote:

полученный ответ сохрани в xml, там будет видна и причина по которой запрос отклонен

"Unsupported application data format" - что может значить?

всё что угодно - проверяйте корректность запроса в первую очередь
для проверки - запрос сохраните в xml и киньте текст сюда, может кто и увидит в чём косяк