Интеграция с 1С

Stedar wrote:

mevgenym wrote:платформу обновите

На 8.3 взлетел. Хм, но это как бы не выход, у клиента 8.2. Ладно попробую последний релиз 8.2 и посмотрю что получится.

на крайнем 130 релизе 8.2 всё работает, а 76 в этом плане подглюкивает

Добрый день! Подскажите, пожалуйста, при отправке заявки с операцией IncomingOperation получаю в ответ результат с ошибкой

MERC14383">Хозяйствующий субъект-инициатор запроса должен быть связан с обслуживающим предприятием.

Хозсубъект - получатель связан с предприятием получателем. Поясните, пожалуйста, какая еще нужна связь.

Заранее Спасибо!

Хозяйствующий субъект-инициатор должен быть связан
Хозсубъект - получатель связан

не моя тема, конечно, но у вас вроде как ответ прям в вопросе написан

Как понимать обслуживающее предприятие?

ваш поднадзорный.
где вы фактически находитесь

Оформление транспортной партии (Реализация).
Выкладываю свои процедуры, процедуры рабочие, оформляем около тысячи накладных в день.
Да можно еще улучшить, но собираюсь в отпуск и переделывать пока не буду.
Если какую - нибудь пропустил, обращайтесь

Процедура СформироватьТранспортнуюПартию(ПараметрыЗапроса) Экспорт

Метод = "prepareOutcomingConsignmentRequest";

// + Подготовка пакетов
ФабрикаXDTO_AM = ПолучитьФабрикуXDTO_AM();
ФункцияXDTO = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/mercury/applications", Метод);
SubmitRequestXDTO = ПодготовитьОбъект_SubmitRequestXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса);
ApplicationXDTO = ПодготовитьОбъект_ApplicationXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса);
ApplicationDataWrapper = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/application", "ApplicationDataWrapper");
EnvelopeXDTO = ПодготовитьОбъект_EnvelopeXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса);
EnvelopeXDTO.Body = ФабрикаXDTO_AM.Создать("http://schemas.xmlsoap.org/soap/envelope/", "Body");

Для Каждого стр Из ПараметрыЗапроса.ТаблицаЗанчений Цикл
ЗаполнитьСтрокуТранспортнойПартии(ФабрикаXDTO_AM,ФункцияXDTO,ПараметрыЗапроса,стр);
КонецЦикла; // Для Каждого стр Из ПараметрыЗапроса.Документ Цикл

initiator = ПодготовитьОбъект_initiator(ФабрикаXDTO_AM,ПараметрыЗапроса,ИСТИНА);

ФункцияXDTO.localTransactionId = ПараметрыЗапроса.НомерДокмента;
ФункцияXDTO.initiator = initiator;

ApplicationDataWrapper.Добавить(ФормаXML.Элемент, ФункцияXDTO.Тип().URIПространстваИмен, Метод, ФункцияXDTO);
ApplicationXDTO.data = ApplicationDataWrapper;

SubmitRequestXDTO.application = ApplicationXDTO;
EnvelopeXDTO.Body.Добавить(ФормаXML.Элемент, SubmitRequestXDTO.Тип().URIПространстваИмен, "submitApplicationRequest", SubmitRequestXDTO);
// - Подготовка пакетов

ТелоXML = Новый ЗаписьXML;
ТелоXML.УстановитьСтроку("UTF-8");
ФабрикаXDTO_AM.ЗаписатьXML(ТелоXML, EnvelopeXDTO);
Строка = ТелоXML.Закрыть();

Ответ = ВыполнитьЗапросВЕТИС(Строка, ПараметрыЗапроса, ФабрикаXDTO_AM);

ПроцедурыЭДО.ОбновитьСтатусыДокументов(Ответ);

КонецПроцедуры // Процедура СформироватьТранспортнуюПартию(ПараметрыЗапроса)

Функция ПолучитьФабрикуXDTO_AM() Экспорт

ОпределениеWS = WSСсылки.ApplicationManagementsServiceTest.ПолучитьWSОпределения();

МассивURI = Новый Массив;
МассивURI.Добавить("http://api.vetrf.ru/schema/cdm/application/ws-definitions");
МассивURI.Добавить("http://api.vetrf.ru/schema/cdm/base/ws-definitions");

ФабрикаWS = Новый ФабрикаXDTO(ОпределениеWS.ФабрикаXDTO.ЭкспортМоделиXDTO(МассивURI), ФабрикаXDTO.Пакеты);

Пакеты = Новый Массив;
Пакеты.Добавить(ФабрикаXDTO.Пакеты.Получить("http://api.vetrf.ru/schema/cdm/mercury/applications"));
Пакеты.Добавить(ФабрикаXDTO.Пакеты.Получить("http://schemas.xmlsoap.org/soap/envelope/"));
Для Каждого Пакет Из ФабрикаWS.Пакеты Цикл
Пакеты.Добавить(Пакет);
КонецЦикла;

ФабрикаXDTO_AM = Новый ФабрикаXDTO(, Пакеты);

Возврат ФабрикаXDTO_AM;

КонецФункции // ПолучитьФабрикуXDTOApplication()

Функция ПодготовитьОбъект_SubmitRequestXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

SubmitRequestXDTO = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/application/ws-definitions", "submitApplicationRequest");
SubmitRequestXDTO.apiKey = ПараметрыЗапроса.НастройкаПодключения.Ключ;

Возврат SubmitRequestXDTO;

КонецФункции // Функция ПодготовитьОбъект_ApplicationXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Функция ПодготовитьОбъект_ApplicationXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Application = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/application", "Application");
Application.serviceId = ПараметрыЗапроса.НастройкаПодключения.ИдентификаторСервиса;
Application.issuerId = ПараметрыЗапроса.НастройкаПодключения.ИдентификаторХС;
Application.issueDate = ПараметрыЗапроса.ДатаДокумента;

Возврат Application;

КонецФункции // Функция ПодготовитьОбъект_ApplicationXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Функция ПодготовитьОбъект_EnvelopeXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

EnvelopeXDTO = ФабрикаXDTO_AM.Создать("http://schemas.xmlsoap.org/soap/envelope/", "Envelope");;

Возврат EnvelopeXDTO;

КонецФункции // Функция ПодготовитьОбъект_ApplicationXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Процедура ЗаполнитьСтрокуТранспортнойПартии(ФабрикаXDTO_AM,ФункцияXDTO,ПараметрыЗапроса,стр)

// + Подготовка пакетов
Delivery = ПодготовитьОбъект_DeliveryXDTO(ФабрикаXDTO_AM,стр);
Сonsignor = ПодготовитьОбъект_СonsignorXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса);
Сonsignee = ПодготовитьОбъект_СonsigneeXDTO(ФабрикаXDTO_AM,стр.Контрагент.GUIDмеркурий,стр.ТорговаяТочка.GUIDмеркурий);
Сonsignment = ПодготовитьОбъект_СonsignmentXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса,стр);
AccompanyingForms = ПодготовитьОбъект_AccompanyingFormsXDTO(ФабрикаXDTO_AM,стр);
// - Подготовка пакетов

Delivery.accompanyingForms = AccompanyingForms;
Delivery.consignee = Сonsignee;
Delivery.consignor = Сonsignor;
Delivery.deliveryDate = ТекущаяДата();
Delivery.consignment.Добавить(Сonsignment);

ФункцияXDTO.delivery.Добавить(Delivery);

КонецПроцедуры // Процедура ЗаполнитьСтрокуТранспортнойПартии()

Функция ПодготовитьОбъект_initiator(ФабрикаXDTO_AM,ПараметрыЗапроса,ВетВрач = ЛОЖЬ)

initiator = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/common", "User");

Если ВетВрач Тогда
initiator.login = ПараметрыЗапроса.ВетВрачЛогин;
Иначе
initiator.login = ПараметрыЗапроса.НастройкаПодключения.ПользовательВЕТИС;
КонецЕсли; // Если ВетВрач Тогда

Возврат initiator;

КонецФункции // Функция ПодготовитьОбъектListOptions(ФабрикаXDTO)

Функция ПодготовитьОбъект_DeliveryXDTO(ФабрикаXDTO_AM,стр)

Delivery = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/mercury/vet-document", "Delivery");

Возврат Delivery;

КонецФункции // Функция ПодготовитьОбъект_DeliveryXDTO(ФабрикаXDTO_AM,стр)

Функция ПодготовитьОбъект_СonsignorXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Consignor = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/cerberus/enterprise", "BusinessMember");
Enterprise = ПодготовитьОбъект_enterprise(ФабрикаXDTO_AM,ПараметрыЗапроса);
BusinessEntity = ПодготовитьОбъект_businessEntity(ФабрикаXDTO_AM,ПараметрыЗапроса);

Consignor.enterprise = Enterprise;
Consignor.businessEntity = BusinessEntity;

Возврат Consignor;

КонецФункции // Функция ПодготовитьОбъект_consignorXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Функция ПодготовитьОбъект_СonsigneeXDTO(ФабрикаXDTO_AM,ИдентификаторКонтрагента,ИдентификаторТорговойТочки)

Сonsignee = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/cerberus/enterprise", "BusinessMember");
Enterprise = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/cerberus/enterprise", "Enterprise");
BusinessEntity = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/cerberus/enterprise", "BusinessEntity");

BusinessEntity.guid = ИдентификаторКонтрагента;
Enterprise.guid = ИдентификаторТорговойТочки;

Сonsignee.enterprise = Enterprise;
Сonsignee.businessEntity = BusinessEntity;

Возврат Сonsignee;

КонецФункции // Функция ПодготовитьОбъект_СonsigneeXDTO(ФабрикаXDTO_AM,ИдентификаторКонтрагента,ИдентификаторТорговойТочки)

Функция ПодготовитьОбъект_СonsignmentXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса,строка)

Сonsignment = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/mercury/vet-document", "Consignment");
Unit = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/common", "Unit");
SourceStockEntry = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/mercury/vet-document", "StockEntry");
PackingFormList = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/common", "PackingFormList");
PackingForm = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/common", "PackingForm");

Unit.uuid = строка.ЕдиницаИзмерения.UUIDМеркурий;
SourceStockEntry.uuid = строка.ЗаписьСкладскогоЖурнала;

Сonsignment.volume = строка.Количество;
Сonsignment.unit = Unit;

Если ЗначениеЗаполнено(строка.Упаковка) Тогда

PackingForm.name = строка.Упаковка.Наименование;
PackingForm.uuid = строка.Упаковка.GUIDМеркурий;
PackingFormList.packingForm.Добавить(PackingForm);

Сonsignment.packingList = PackingFormList;
Сonsignment.packingAmount = строка.КоличествоУпаковок;

КонецЕсли; // Если ЗначениеЗаполнено(стр.Упаковка) Тогда

Сonsignment.sourceStockEntry = SourceStockEntry;

Возврат Сonsignment;

КонецФункции // Функция ПодготовитьОбъект_СonsignmentXDTO(ФабрикаXDTO_AM,ПараметрыЗапроса)

Функция ПодготовитьОбъект_AccompanyingFormsXDTO(ФабрикаXDTO_AM,стр)

AccompanyingForms = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/mercury/vet-document", "ConsignmentDocumentList");
Waybill = ПодготовитьОбъект_WaybillXDTO(ФабрикаXDTO_AM,стр);
VetCertificate = ПодготовитьОбъект_VetCertificateXDTO(ФабрикаXDTO_AM,стр);

AccompanyingForms.waybill = Waybill;
AccompanyingForms.vetCertificate.Добавить(VetCertificate);

Возврат AccompanyingForms;

КонецФункции // Функция ПодготовитьОбъект_AccompanyingFormsXDTO(ФабрикаXDTO_AM,стр)

Функция ПодготовитьОбъект_enterprise(ФабрикаXDTO_AM,ПараметрыЗапроса)

Enterprise = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/cerberus/enterprise", "Enterprise");

Enterprise.guid = ПараметрыЗапроса.ИдентификаторПредприятия;

Возврат Enterprise;

КонецФункции // Функция ПодготовитьОбъект_enterprise(ФабрикаXDTO)

Функция ПодготовитьОбъект_businessEntity(ФабрикаXDTO_AM,ПараметрыЗапроса)

BusinessEntity = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/cerberus/enterprise", "BusinessEntity");

BusinessEntity.guid = ПараметрыЗапроса.ИдентификаторХС;

Возврат BusinessEntity;

КонецФункции // Функция ПодготовитьОбъект_businessEntity(ФабрикаXDTO_AM,ПараметрыЗапроса)

Функция ПодготовитьОбъект_WaybillXDTO(ФабрикаXDTO_AM,строка)

Waybill = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/shipment", "Waybill");
TransportInfo = ПодготовитьОбъект_TransportInfoXDTO(ФабрикаXDTO_AM,строка);

Waybill.issueNumber = строка.НомерТТН;
Waybill.issueDate = строка.ДатаТТН;
Waybill.type = 1;
Waybill.transportStorageType = строка.СпособХраненияПриПеревозке.Код;
Waybill.transportInfo = TransportInfo;

Возврат Waybill;

КонецФункции // Функция ПодготовитьОбъект_WaybillXDTO(ФабрикаXDTO_AM,строка)

Функция ПодготовитьОбъект_VetCertificateXDTO(ФабрикаXDTO_AM,стр)

VetCertificate = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/mercury/vet-document", "VetDocument");
Purpose = ПодготовитьОбъект_PurposeXDTO(ФабрикаXDTO_AM,стр);
TransportInfo = ПодготовитьОбъект_TransportInfoXDTO(ФабрикаXDTO_AM,стр);
ConfirmedBy = ПодготовитьОбъект_ConfirmedByXDTO(ФабрикаXDTO_AM,стр);

VetCertificate.purpose = Purpose;
VetCertificate.transportInfo = TransportInfo;
VetCertificate.transportStorageType = стр.СпособХраненияПриПеревозке.Код;
VetCertificate.cargoInspected = ИСТИНА;
VetCertificate.cargoExpertized = ЛОЖЬ;
VetCertificate.confirmedBy = ConfirmedBy;
VetCertificate.locationProsperity = стр.БлагополучиеМестности.Наименование;

Возврат VetCertificate;

КонецФункции // Функция ПодготовитьОбъект_VetCertificateXDTO(ФабрикаXDTO_AM,стр)

Функция ПодготовитьОбъект_TransportInfoXDTO(ФабрикаXDTO_AM,строка)

TransportInfo = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/shipment", "TransportInfo");
TransportNumber = ПодготовитьОбъект_TransportNumberXDTO(ФабрикаXDTO_AM,строка);

TransportInfo.transportType = 1;
TransportInfo.transportNumber = TransportNumber;
Возврат TransportInfo;

КонецФункции // Функция ПодготовитьОбъект_TransportInfoXDTO(ФабрикаXDTO_AM,строка)

Функция ПодготовитьОбъект_PurposeXDTO(ФабрикаXDTO_AM,стр)

Purpose = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/common", "Purpose");

Purpose.guid = стр.Цель.GUIDМеркурий;

Возврат Purpose;

КонецФункции // Функция ПодготовитьОбъект_PurposeXDTO(ФабрикаXDTO_AM,стр)

Функция ПодготовитьОбъект_TransportInfoXDTO(ФабрикаXDTO_AM,строка)

TransportInfo = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/shipment", "TransportInfo");
TransportNumber = ПодготовитьОбъект_TransportNumberXDTO(ФабрикаXDTO_AM,строка);

TransportInfo.transportType = 1;
TransportInfo.transportNumber = TransportNumber;
Возврат TransportInfo;

КонецФункции // Функция ПодготовитьОбъект_TransportInfoXDTO(ФабрикаXDTO_AM,строка)

Функция ПодготовитьОбъект_TransportNumberXDTO(ФабрикаXDTO_AM,строка)

TransportNumber = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/shipment", "TransportNumber");

TransportNumber.vehicleNumber = строка.ТранспортноеСредство.Код;

Возврат TransportNumber;

КонецФункции // Функция ПодготовитьОбъект_WaybillXDTO(ФабрикаXDTO_AM,строка)

Функция ПодготовитьОбъект_ConfirmedByXDTO(ФабрикаXDTO_AM,стр)

ConfirmedBy = ФабрикаXDTO_AM.Создать("http://api.vetrf.ru/schema/cdm/argus/common", "User");

ConfirmedBy.fio = стр.ВетВрачПредставление;
ConfirmedBy.post = стр.ВетВрачДолжность;

Возврат ConfirmedBy;

КонецФункции // Функция ПодготовитьОбъект_ConfirmedByXDTO(ФабрикаXDTO_AM,стр)

Функция ВыполнитьЗапросВЕТИС(Строка, ПараметрыЗапроса, ФабрикаXDTO_AM) Экспорт

ПараметрыПодключения = ПараметрыЗапроса.НастройкаПодключения;

СтруктураОтвета = Новый Структура();
СтруктураОтвета.Вставить("Документ", ПараметрыЗапроса.Ссылка);
СтруктураОтвета.Вставить("Статус");
СтруктураОтвета.Вставить("КодСостояния");
СтруктураОтвета.Вставить("ИдентификаторЗапроса");
СтруктураОтвета.Вставить("ТекстЗапроса", Строка);

ЗапросWeb = Новый HTTPЗапрос("platform/services/ApplicationManagementService");
ЗапросWeb.УстановитьТелоИзСтроки(Строка);

Если ЗначениеЗаполнено(ПараметрыПодключения.Порт) Тогда
СоединениеWeb = Новый HTTPСоединение(ПараметрыПодключения.АдресСервиса, ПараметрыПодключения.Порт, ПараметрыПодключения.Логин, ПараметрыПодключения.Пароль,,Истина);
Иначе
СоединениеWeb = Новый HTTPСоединение(ПараметрыПодключения.АдресСервиса,, ПараметрыПодключения.Логин, ПараметрыПодключения.Пароль,,Истина);
КонецЕсли; // Если ЗначениеЗаполнено(ПараметрыПодключения.НастройкаПодключения.Порт) Тогда

ОтветWeb = СоединениеWeb.ОтправитьДляОбработки(ЗапросWeb);

Если (ОтветWeb.КодСостояния <> 200) Тогда

СтруктураОтвета.Вставить("КодСостояния",ОтветWeb.КодСостояния); // Кривой запрос

Иначе

СтруктураОтвета.Вставить("КодСостояния",ОтветWeb.КодСостояния);

ОтветXML = Новый ЧтениеXML;
ОтветXML.УстановитьСтроку(ОтветWeb.ПолучитьТелоКакСтроку("UTF-8"));

ОтветXDTO = ФабрикаXDTO.ПрочитатьXML(ОтветXML);

Статус = ОтветXDTO.Body.submitApplicationResponse.application.status;

Если Статус = "ACCEPTED" Тогда

СтруктураОтвета.Статус = Перечисления.СтатусыЭДО.ACCEPTED;
СтруктураОтвета.ИдентификаторЗапроса = ОтветXDTO.Body.submitApplicationResponse.application.applicationId;

Иначе

СтруктураОтвета.Статус = Перечисления.СтатусыЭДО[ОтветXDTO.status];

КонецЕсли; // Если Статус = "ACCEPTED" Тогда

КонецЕсли; // Если (ОтветWeb.КодСостояния <> 200) Тогда

Возврат СтруктураОтвета;

КонецФункции // Функция ВыполнитьЗапросВЕТИС(Строка, ПараметрыПодключения, ФабрикаXDTO_AM) Экспорт

ВРОДЕ НИЧЕГО НЕ ЗАБЫЛ

Готовы: производственные партии, объединение журналов, складской журнал. Кому надо пишите

Здравствуйте!

Пытаюсь сделать интеграцию на основе http://infostart.ru/public/560823/.
Вопрос возник по полю localTransactionId
В частности, пробую обработку получения остатков из этой статьи. Там используется GetStockEntryListOperation, значение localTransactionId="" (пустое). В тестовой версии Меркурия все работает. В рабочей версии Меркурия выдается ошибка MERC37181, текст сообщения точно не помню, но смысл такой, что пустое значение для localTransactionId недопустимо. В описании GetStockEntryListOperation ошибки с таким номером нет.
Подскажите, пожалуйста, каким значение надо заполнять это поле и что оно означает?

Спасибо.

gni wrote: пустое значение для localTransactionId недопустимо.

просто заполняйте туда какой-нибудь номер. например номер документа по которому делается транзакция.

kiv1c wrote:

gni wrote: пустое значение для localTransactionId недопустимо.

просто заполняйте туда какой-нибудь номер. например номер документа по которому делается транзакция.

Я пробовал, но опять выходила ошибка (сейчас, к сожалению не могу повторить, немного позже напишу полное наименование), что операции с таким номером не найдено...

Все, разобрался.
Оказывается, указывал неверный GUID своей площадки. В тестовой версии и в рабочей они оказывается у нас отличаются.

Спасибо.

сделал выгрузку cf со всеми необходимыми xdto пакетами
https://drive.google.com/open?id=0ByksGTNeAAfKdno5VXVwMFhPVU0

Добрый день коллеги! Вопрос: Сейчас пытаюсь настроить общение 1С с тестовым API Меркурия. При попытке обратиться к нему методом GetPurposeList возникает ошибка.
Вызываю метод с у объекта WSпрокси. WSпрокси.ТочкаПодключения.Местоположение = https://api2.vetrf.ru:8002/platform/services/DictionaryService. Пароль и логин пользователя указаны.
При вызове метода на вход подаю объект с типом: ТипОбъектаXDTO и значением {http://api.vetrf.ru/schema/cdm/base}ListOptions.
При отправке тех же значений на основную API возвращается ошибка авторизации, но оно и правильно потому что там еще не зарегистрированы.
Что я делаю не так?

Ошибка: {Обработка.ВетисНормативноСправочнаяИнформация(88)}: Ошибка при вызове метода контекста (GetPurposeList): Ошибка вызова операции сервиса: {http://api.vetrf.ru/schema/cdm/registry/service}ictionaryServiceBindingQSService:GetPurposeList()
Возврат Прокси.GetPurposeList(ПолучитьXDTO_ПараметрыСписка(Количество, НачальныйНомер));
по причине:
Ошибка вызова операции сервиса: {http://api.vetrf.ru/schema/cdm/registry/service}ictionaryServiceBindingQSService:GetPurposeList()
по причине:
Ошибка SOAP сервера: BEA-382513: OSB Replace action failed updating variable "body": Error parsing XML: {err}FORG0005: expected exactly one item, got 0 items

FruttyMan wrote: Error parsing XML: {err}FORG0005: expected exactly one item, got 0 items

кажется что-то вы ему недодали, вангую что listOptions.

и при этом ошибка авторизации на боевом вам прилетает закономерно, т.к. она первичнее
http://help.vetrf.ru/images/3/3b/ConnectToGate.png
вот рабочий кодик для тестового сервера: (надеюсь WSссылку знаете как закинуть)

почитайте здесь может поможет, номер ошибки ваш
http://www.fsvps.ru/vetrf-forum/posts/list/645/6855.page;jsessionid=36d07b6ea859d4fc817a8a0e74b4#40150

для справочников есть проверенный код, берите пользуйтесь

вот так выглядит полная выборка PurposeList из меркурия, код минимальный накосячить трудно